What BasinC can do
First, experiment
This short tutorial is designed for beginners to Sinclair BASIC programming, and will show (with screenshots) what the language is capable of at a basic level. More advanced tutorials can be found elsewhere in the help file.
Program BasinC
Sinclair BASIC can do a lot of things, but to make it work you have to give it a set of instructions called a computer program.
Each set of instructions is shown in a list called a listing. You'll see that the program listings contain several sections each beginning with a number - 10, 20 and so on. Each section is called a line in the program (even if it takes up two lines on the screen), and it contains one or more instructions for the computer.
In each program line, you'll see whole words or abbreviations containing two or more letters, such as PRINT, LET, RND, PI, PAPER and GO TO. These are called keywords.
As you key in a program line, it will appear in the main BasinC editor window, as you'd expect. When you get to the end of the program line, press the RETURN key. BasinC will emit a high "beep" if the line is correctly typed, and a low beep if you have made a mistake. If you get a low beep, BasinC will refuse to accept the line and flash the editor cursor red at the point you made the mistake. Beware - even though BasinC thinks the line may be correct, it may not be.
When you have entered all the lines, type "RUN" on a new line. Now press RETURN and BasinC will spring into action and run your program.
How to restart a program
Some of these programs - like "Stars and Stripes" - come to an end and produce the report 0 Ok, and the last line number of the program. This means that the whole program has finished. To start again, simply type "RUN" again, followed by RETURN.
Other programs either keep running, like "Manic Mosaic", or start again automatically, like "Shimmering Sunrise". To stop these programs, press ESCAPE. Hold this key down until the program stops and the BREAK report appears. To restart, just type RUN again, followed by RETURN.
How to correct mistakes
The editor acts just like any other text editor. If you make a mistake keying in a line, just move to the place you spotted it, and press DEL or BACKSPACE and re-type it. As explained earlier, if you have made a mistake and don't catch it before you enter the line, then BasinC will emit a low beep and move the cursor to the place that the mistake occurred, colouring the cursor red to draw your attention. If you do manage to get past BasinC's error checking (which is possible - some mistakes are actually syntactically correct BASIC commands) then the program may not work as intended. BasinC provides a number of tools (which you can read about in the debugging chapter). You can correct the error by moving the cursor up or down to the line in question and edit it there.
How to begin a new program
When you have finished with a program and want to enter a totally new program, wait until it ends or press the ESCAPE key to stop it.
You then have the choice of two ways for erasing the old program from BasinC's memory. One way is to enter "NEW" followed by RETURN. The display window will go black for a moment and then the copyright message will appear, followed by BasinC's editor window, which will pop to the front.
Alternatively, and more easily, you can use the File menu's NEW option (or the NEW button on the Toolbar). This has essentially the same effect as the NEW command, with a few differences which will really only interest advanced users, and so need not concern us here.
Example programs
As promised, here are some programs for you to try in BasinC. You can either type them in yourself, or you can copy and paste them into the editor.
Names
10 BORDER 1: INK RND*7 20 PAPER RND*7 30 PRINT " Sinclair BASIC"; 40 GO TO 10
The words "Sinclair BASIC" appear in many colours all over the screen. The program then pauses and a message, "Scroll?", appears at the bottom of the screen. To make the display "scroll" up, press any key except N, SPACE and ESCAPE. If you do stop the scrolling, then returning to the editor and typing "RUN" followed by RETURN will flood the screen again, in different colours.
Try this
In line 30, change " Sinclair BASIC" to your name in quote marks (") - for example
30 PRINT "Lee Forgarty ";
Remember to include the semicolon (;). You'll then see your name appear all over the screen.
Patterns
10 LET a$="" 20 FOR x=1 TO 7 30 LET a$=a$+CHR$ (RND*14+129) 40 NEXT X 50 INK RND*7 60 BORDER RND*7 70 PRINT a$; 80 GO TO 70
A geometric colour pattern forms on the screen when you run the program. When the screen is full, the display pauses with the "Scroll?" message. To see more of the same display, press any key (except N, SPACE and ESCAPE) to make the pattern move up. To see a new kind of pattern in a different combination of colours, press N when the "Scroll?" message appears. Then return to the editor and type "RUN" followed by RETURN.
Try this
In line 20, change 7 to another number to get a different kind of pattern. Try 8, for example.
Flashing Circles
10 BORDER 0:
PAPER 0:
CLS
20 CIRCLE INK RND*6; FLASH RND;120+RND*8,80+RND*6,RND*80
30 BEEP 0.1,RND*60
40 IF RND>.9 THEN GO TO 60
50 GO TO 20
60 FOR y=-2 TO 4
70 FOR x=0 TO 6
80 BORDER x
90 BEEP .05,x*y
100 NEXT x
110 NEXT y
120 RUN
A set of almost concentric flashing circles in a range of different colours builds up on the screen. Then suddenly the border flashes, the computer produces a trilling sound, and a new set of circles appears.
Try this
Try entering PAPER 7 and press RETURN. Then key in line 20 again, missing out the two keywords FLASH and RND; and the circles will no longer flash.
Manic Mosaic
5 BORDER 0:
CLS
10 LET h=16:
LET v=11
20 LET x=INT (RND*3-1):
LET y=INT (RND*3-1)
30 INK RND*7
40 FOR z=1 TO 20
50 PRINT AT v,h;CHR$ 143
60 LET h=h+x
70 LET v=v+y
80 IF h<0 THEN LET h=31
90 IF h>31 THEN LET h=0
100 IF v<0 THEN LET v=21
110 IF v>21 THEN LET v=0
120 NEXT z
130 GO TO 20
A coloured square dashes to and fro all over the screen, building up a coloured pattern. A different pattern is produced every time you restart the program.
Try this
In line 50, change 143 to 42 and you'll see stars! Try other numbers from 33 to 142. Consult the Character Set chart to check what will happen.
Polyhedra
5 BORDER 1:
PAPER 6:
CLS
10 INPUT n
20 FOR r=20 TO 80 STEP 2
25 LET x=128:
LET y=87
30 LET h1=x-r:
LET v1=y
35 PLOT h1,v1
40 FOR a=0 TO 361 STEP 360/n
50 LET h2=x-r*COS (a*PI/180)
60 LET v2=y+r*SIN (a*PI/180)
70 DRAW h2-h1,v2-v1
80 LET h1=h2:
LET v1=v2
85 BEEP 0.02,r-20
90 NEXT a
100 NEXT r
At first, you see a blank screen. Key in 6, then press RETURN. A six-sided shape builds up. Restart the program when it has finished and key in another number to get a shape with a different number of sides.
Try this
In line 20, change 2 to another number. The patteren builds more quickly if the number is bigger, and the polyhedra (many-sided figures) are farther apart.
Stars and Stripes
10 INK 2
20 PAPER 7
30 CLS
40 FOR x=28 TO 148 STEP 20
50 FOR z=0 TO 11
60 PLOT 16,z+x:
DRAW 216,0
70 NEXT z
80 NEXT x
90 PLOT 16,28:
DRAW 0,131
100 PLOT 232,28:
DRAW 0,131
110 PAPER 1
120 INK 7
130 FOR x=2 TO 8 STEP 2
140 PRINT AT x,2;"* * * * * *"
150 PRINT AT x+1,2;" * * * * * "
160 NEXT x
170 PRINT AT x,2;"* * * * * *"
The United States flag appears on the screen.
Try this
Change the colour numbers of the flag. The stripe colour is at line 10, the stars at line 120 and the background to the stars is at line 110.
Shimmering Sunrise
10 BORDER RND*6 20 INK RND*7 30 PAPER RND*6 40 CLS 50 LET z=RND*10+2 60 FOR x=0 TO 174 STEP z 70 PLOT 128,0 80 DRAW -128,x 90 BEEP .01,x/3 100 NEXT x 110 FOR x=-127 TO 127 STEP z 120 PLOT 128,0 130 DRAW x,175 140 BEEP .01,60 150 NEXT x 160 FOR x=174 TO 0 STEP -z 170 PLOT 128,0 180 DRAW 127,x 190 BEEP .01,x/3 200 NEXT x 210 PAUSE 200 220 GO TO 10
A picture like a shimmering sunrise builds up in different colours every few seconds. If the screen goes blank, just wait. A new sunrise soon dawns.
Try this
In line 210, change 200 to another number in order to alter the time for which each sunrise stays on the screen. 200 is equal to 4 seconds.
What Next?
Now you have a choice. If you want to keep any of these programs (they are not provided in BasinC's example programs library) then you can read the chapter on How to save your own programs. If you want to carry on experimenting with BasinC, you can learn more about programming by jumping to the next chapter. So far you have just tried programs out, without necessarily understanding how they work. The next chapter will explain some of the features of programming in Sinclair BASIC.
